सारांश
कई टैक्स ब्रैकेट के आधार पर कुल आयकर की गणना करने के लिए, आप VLOOKUP और संरचित दर का उपयोग कर सकते हैं जैसा कि उदाहरण में दिखाया गया है। G5 में सूत्र है:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
जहाँ "inc" (G4) और "रेट्स" (B5: D11) का नाम श्रेणी है, और कॉलम D एक सहायक स्तंभ है जो प्रत्येक ब्रैकेट में कुल संचित कर की गणना करता है।
पृष्ठभूमि और संदर्भ
यूएस टैक्स सिस्टम "प्रगतिशील" है, जिसका अर्थ है कि उच्च कर योग्य आय वाले लोग उच्च संघीय कर दर का भुगतान करते हैं। ऊपरी और निचली सीमा द्वारा परिभाषित कोष्ठक में दरों का मूल्यांकन किया जाता है। किसी दिए गए ब्रैकेट में आने वाली आय की राशि को उस ब्रैकेट के लिए इसी दर पर लगाया जाता है। कर योग्य आय बढ़ने के साथ, आय पर अधिक कर कोष्ठक पर कर लगाया जाता है। कई करदाता इसलिए कई अलग-अलग दरों का भुगतान करते हैं।
दिखाए गए उदाहरण में, टैक्स ब्रैकेट्स और दरें संयुक्त राज्य अमेरिका में 2019 कर वर्ष के लिए एकल फाइलरों के लिए हैं। नीचे दी गई तालिका $ 50,000 की कर योग्य आय के लिए मैन्युअल गणना दर्शाती है:
| कंस | हिसाब | कर |
|---|---|---|
| 10% | ($ 9,700 - $ 0) x 10% | $ 970.00 |
| 12% | ($ 39,475 - $ 9,700) x 12% | $ 3,573.00 |
| 22% | ($ 50,000- $ 39,475) x 22% | $ 2,315.50 |
| 24% | एनए | $ 0.00 |
| 32% | एनए | $ 0.00 |
| 35% | एनए | $ 0.00 |
| 37% | एनए | $ 0.00 |
इसलिए कुल कर $ 6,858.50 है। (दिखाए गए उदाहरण में 6,859 के रूप में प्रदर्शित)।
नोट्स सेट करें
1. यह सूत्र "अनुमानित मैच मोड" में VLOOKUP फ़ंक्शन पर निर्भर करता है। जब अनुमानित मैच मोड में, VLOOKUP एक उच्च मान नहीं मिलने तक तालिका में लुकअप मान (जो आरोही क्रम में क्रमबद्ध होना चाहिए) के माध्यम से स्कैन करेगा। फिर यह "स्टेप बैक" होगा और पिछली पंक्ति से एक मान लौटाएगा। एक सटीक मैच की स्थिति में, VLOOKUP मिलान वाली पंक्ति से परिणाम लौटाएगा।
2. वास्तविक संचयी कर राशियों को पुनः प्राप्त करने के लिए VLOOKUP के क्रम में, इन्हें तालिका डी में एक सहायक स्तंभ के रूप में तालिका में जोड़ा गया है। D6 में सूत्र, नीचे कॉपी किया गया है:
=((B6-B5)*C5)+D5
प्रत्येक पंक्ति में, यह सूत्र उस कोष्ठक में आय से ऊपर की पंक्ति से दर लागू करता है।
3. पठनीयता के लिए, निम्नलिखित नामित श्रेणियाँ परिभाषित की गई हैं: "inc" (G4) और "दरें" (B5: D11)।
स्पष्टीकरण
G5 में, पहले VLOOKUP को इन इनपुट के साथ सीमांत दर पर संचयी कर प्राप्त करने के लिए कॉन्फ़िगर किया गया है:
- लुकअप मान "inc" (G4) है
- लुकअप तालिका "दरें" (B5: D11) है
- कॉलम नंबर 3 है, संचयी कर
- मैच प्रकार 1 = अनुमानित मैच है
VLOOKUP(inc,rates,3,1) // returns 4,543
$ 50,000 की कर योग्य आय के साथ, VLOOKUP, अनुमानित मैच मोड में, 39,475 से मेल खाता है, और 4,543 रिटर्न करता है, कुल कर $ 39,475 तक।
दूसरा VLOOKUP शेष आय की गणना करता है:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
इस तरह की गणना:
(50,000-39,475) = 10,525
अंत में, तीसरे VLOOKUP को (शीर्ष) सीमांत कर की दर मिलती है:
VLOOKUP(inc,rates,2,1) // returns 22%
यह पिछले चरण में गणना की गई आय से गुणा किया जाता है। पूर्ण सूत्र इस प्रकार हल किया गया है:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
सीमांत और प्रभावी दरें
सेल G6 में शीर्ष सीमांत दर शामिल है, जिसकी गणना VLOOKUP के साथ की गई है:
=VLOOKUP(inc,rates,2,1) // returns 22%
G7 में प्रभावी कर की दर कुल कर योग्य आय से विभाजित कर है:
=G5/inc // returns 13.7%
नोट: मैं एक्सेल यूनिवर्सिटी में जेफ लेनिंग के ब्लॉग पर इस फॉर्मूले में भाग गया। यह एक बेहतरीन उदाहरण है कि कैसे VLOOKUP का उपयोग लगभग मैच मोड में किया जा सकता है, और यह भी कि कैसे VLOOKUP को एक ही सूत्र में कई बार उपयोग किया जा सकता है।
