एक्सेल फॉर्मूला: रैंक अगर फॉर्मूला -

सामान्य सूत्र

=COUNTIFS(criteria_range,criteria,values,">"&value)+1

सारांश

एक या अधिक मानदंडों का उपयोग करके किसी सूची में आइटम रैंक करने के लिए, आप COUNTIFS फ़ंक्शन का उपयोग कर सकते हैं। दिखाए गए उदाहरण में, E5 में सूत्र है:

=COUNTIFS(groups,C5,scores,">"&D5)+1

जहाँ "समूह" नाम की श्रेणी C5: C14 है, और "स्कोर" नाम की श्रेणी D5: D14 है। परिणाम प्रत्येक व्यक्ति के लिए अपने स्वयं के समूह में एक रैंक है।

नोट: हालाँकि डेटा को स्क्रीनशॉट में समूह द्वारा क्रमबद्ध किया गया है, लेकिन फार्मूला बिना डेटा के ठीक काम करेगा।

स्पष्टीकरण

हालाँकि Excel में RANK फ़ंक्शन है, लेकिन सशर्त रैंक करने के लिए RANKIF फ़ंक्शन नहीं है। हालाँकि, आप आसानी से COUNTIFS फ़ंक्शन के साथ एक सशर्त RANK बना सकते हैं।

COUNTIFS फ़ंक्शन दो या अधिक मानदंडों का उपयोग करके एक सशर्त गणना कर सकता है। मानदंड रेंज / मानदंड जोड़े में दर्ज किए जाते हैं। इस मामले में, पहला मानदंड उसी समूह में गिनती को प्रतिबंधित करता है, जिसका नाम "श्रेणी" (C5: C14) है:

=COUNTIFS(groups,C5) // returns 5

अपने आप से, यह समूह "ए" में कुल समूह सदस्यों को वापस कर देगा, जो 5 है।

दूसरा मापदंड D5 से "वर्तमान स्कोर" से अधिक स्कोर की गिनती को प्रतिबंधित करता है:

=COUNTIFS(groups,C5,scores,">"&D5) // returns zero

दो मापदंड पंक्तियों को गिनने के लिए एक साथ काम करते हैं जहाँ समूह A है और स्कोर अधिक है। सूची (हन्नाह) में पहले नाम के लिए, समूह ए में कोई उच्च स्कोर नहीं हैं, इसलिए COUNTIFS शून्य देता है। अगली पंक्ति (एडवर्ड) में, समूह ए में 79 से अधिक तीन स्कोर हैं, इसलिए COUNTIFS 3 रिटर्न। और इसी तरह।

एक उचित रैंक प्राप्त करने के लिए, हम केवल COUNTIFS द्वारा लौटी संख्या में 1 जोड़ते हैं।

रैंक क्रम को उलट देना

क्रम में रैंक क्रम और क्रम को उलटने के लिए (अर्थात सबसे छोटा मान # 1 स्थान पर है) बस ऑपरेटर () से कम का उपयोग करें:

=COUNTIFS(groups,C5,scores,"<"&D5)+1

D5 से अधिक स्कोर की गणना करने के बजाय, यह संस्करण D5 में मूल्य से कम स्कोर की गणना करेगा, रैंक क्रम को प्रभावी ढंग से उलट देगा।

डुप्लिकेट

RANK फ़ंक्शन की तरह, इस पृष्ठ पर सूत्र डुप्लिकेट मानों को समान रैंक प्रदान करेगा। उदाहरण के लिए, यदि किसी विशिष्ट मान को 3 रैंक दिया गया है, और रैंक किए जा रहे डेटा में मूल्य के दो उदाहरण हैं, तो दोनों उदाहरणों को 3 रैंक मिलेगा, और अगली रैंक सौंपी जाएगी 5. व्यवहार की नकल करने के लिए RANK.AVG फ़ंक्शन, जो इस तरह के मामले में औसत रैंक 3.5 प्रदान करेगा, आप इस तरह के एक सूत्र के साथ "सुधार कारक" की गणना कर सकते हैं:

=(COUNTIFS(groups,C5)+1-(COUNTIFS(group,C5,scores,">"&D5)+1)-(COUNTIFS(groups,C5,scores,"<"&D5)+1))/2

ऊपर दिए गए इस सूत्र के परिणाम को मूल रैंक में जोड़ा जा सकता है ताकि एक औसत रैंक प्राप्त हो सके। जब किसी मूल्य का कोई डुप्लिकेट नहीं होता है, तो उपरोक्त कोड शून्य लौटता है और इसका कोई प्रभाव नहीं पड़ता है।