एक्सेल सूत्र: अंतिम शब्द निकालें -

सामान्य सूत्र

=MID(A1,1,FIND("~",SUBSTITUTE(A1," ","~",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))-1)

सारांश

टेक्स्ट स्ट्रिंग से अंतिम शब्द को हटाने के लिए, आप SUBSTITUTE, LEN और FIND की मदद से MID फ़ंक्शन के आधार पर एक सूत्र का उपयोग कर सकते हैं। दिखाए गए उदाहरण में, सेल B5 का सूत्र है:

=MID(B5,1,FIND("~",SUBSTITUTE(B5," ","~",LEN(B5)-LEN(SUBSTITUTE(B5," ",""))))-1)

स्पष्टीकरण

यह सूत्र टेक्स्ट स्ट्रिंग से अंतिम शब्द को हटाने के लिए MID फ़ंक्शन का उपयोग करता है। मुख्य चुनौती यह पता लगाना है कि अंतिम शब्द कहां से शुरू होता है।

सूत्र थोड़ा जटिल है, लेकिन चरण सरल हैं। हम पहले गणना करते हैं कि LEN और SUBSTITUTE का उपयोग करके पाठ में कितने स्थान मौजूद हैं। अगला, हम कुछ जगह अस्पष्ट (उदाहरण) तर्क का उपयोग अंतिम स्थान को टिल्ड (~) से बदलने के लिए SUBSTITUTE फ़ंक्शन में करते हैं। अंत में, हम यह पता लगाने के लिए FIND का उपयोग करते हैं कि टिल्ड कहां है, और MID फ़ंक्शन टिल्ड के बाद सब कुछ त्यागने के लिए।

अंदर-बाहर से काम करते हुए, हम LEN और SUBSTITUTE फ़ंक्शन का उपयोग यह गिनने के लिए करते हैं कि अगले में कितने स्थान हैं:

LEN(B5)-LEN(SUBSTITUTE(B5," ","")) // returns 6

बी 5 में पाठ के लिए, यह 6. लौटाता है। यह पृष्ठ सूत्र के इस हिस्से को अधिक विस्तार से बताता है। यह बताता है कि हम 6 वें स्थान के चरित्र में पाठ को काटना चाहते हैं।

नोट: यदि शब्दों को एक से अधिक स्थानों से अलग किया जाता है, तो आप TRIM फ़ंक्शन के साथ पहले रिक्त स्थान को सामान्य करना चाहेंगे।

संख्या 6 को तब "उदाहरण संख्या" के रूप में दूसरे SUBSTITUTE में प्लग किया जाता है:

SUBSTITUTE(B5," ","~",6) // insert tilde

यहां, हम एक टिल्ड (~) के साथ एक स्थान ("") के 6 वें उदाहरण को बदल रहे हैं। SUBSTITUTE के चलने के बाद, यह इस स्ट्रिंग को लौटाता है:

"It's been seven hours and fifteen~days"

नोट: हम एक टिल्ड (~) का उपयोग केवल इसलिए करते हैं क्योंकि यह शायद ही कभी होने वाला चरित्र है। आप अपनी पसंद के किसी भी पात्र का उपयोग कर सकते हैं, जब तक कि वह स्रोत पाठ में प्रकट न हो।

अगला, हम टिल्ड का पता लगाने के लिए FIND फ़ंक्शन का उपयोग करते हैं:

FIND("~","It's been seven hours and fifteen~days")-1

FIND 34 का रिटर्न देता है, क्योंकि टिल्ड 34 वां कैरेक्टर है। हम इस संख्या से 1 घटाते हैं, क्योंकि हम अंतिम परिणाम में अंतिम स्थान को शामिल नहीं करना चाहते हैं। अब हम सूत्र को सरल बना सकते हैं:

=MID(B5,1,33) // extract final text

MID फ़ंक्शन फिर वर्ण 1-33 लौटाता है:

"It's been seven hours and fifteen"

एक कस्टम सीमांकक के साथ

एक ही सूत्र का उपयोग अलग-अलग परिसीमन के साथ किया जा सकता है। उदाहरण के लिए, अंतिम फ़ॉरवर्ड स्लैश "/" के बाद सभी टेक्स्ट को हटाने के लिए, आप उपयोग कर सकते हैं:

=MID(A1,1,FIND("~",SUBSTITUTE(A1,"/","~",LEN(A1)-LEN(SUBSTITUTE(A1,"/",""))))-1)

अंतिम n शब्द निकालें

आप अंतिम 2 शब्दों, अंतिम 3 शब्दों आदि को हटाने के लिए सूत्र को अनुकूलित कर सकते हैं। सामान्य रूप है:

=MID(A1,1,FIND("~",SUBSTITUTE(A1,d,"~",LEN(A1)-LEN(SUBSTITUTE(A1,d,""))-(n-1)))-1)

जहां d परिसीमन है, और n शब्दों को हटाने की संख्या है।