एक्सेल सूत्र: उन कोशिकाओं की गणना करें जिनमें विशिष्ट पाठ हैं -

सामान्य सूत्र

=COUNTIF(range,"*txt*")

सारांश

उन कोशिकाओं को गिनने के लिए जिनमें कुछ पाठ होते हैं, आप वाइल्डकार्ड के साथ COUNTIF फ़ंक्शन का उपयोग कर सकते हैं। दिखाए गए उदाहरण में, E5 में सूत्र है:

=COUNTIF(B5:B15,"*a*")

स्पष्टीकरण

COUNTIF फ़ंक्शन मापदंड को पूरा करने वाली श्रेणी में कोशिकाओं को गिनता है। उदाहरण के लिए, उस श्रेणी की कोशिकाओं की संख्या गिनने के लिए जिनमें "a" का उपयोग किया जा सकता है:

=COUNTIF(range,"a") // exact match

हालाँकि, ध्यान दें कि यह एक सटीक मिलान है। गिने जाने के लिए, एक सेल में बिल्कुल "ए" होना चाहिए। यदि कक्ष में कोई अन्य वर्ण हैं, तो उसे गिना नहीं जाएगा।

दिखाई गई समस्या के लिए, हम उन कोशिकाओं को गिनना चाहते हैं जिनमें विशिष्ट पाठ होते हैं, जिसका अर्थ है कि पाठ सेल में कहीं भी हो सकता है। ऐसा करने के लिए, हमें वाइल्डकार्ड के रूप में तारांकन (*) वर्ण का उपयोग करने की आवश्यकता है। उदाहरण के लिए, उन कोशिकाओं को गिनने के लिए जिनमें "a" कहीं भी हम उपयोग करते हैं:

=COUNTIF(range,"*a*")

सूत्र में तारांकन का अर्थ है "शून्य सहित किसी भी संख्या में वर्णों का मिलान करें", इसलिए यह पैटर्न किसी भी स्थिति को किसी भी स्थिति में "a" के साथ या अन्य वर्णों के साथ बाईं या दाईं ओर गिना जाएगा। उदाहरण में प्रयुक्त सूत्र सभी एक ही पैटर्न का अनुसरण करते हैं:

=COUNTIF(B5:B15,"*a*") // contains "a" =COUNTIF(B5:B15,"*2*") // contains "2" =COUNTIF(B5:B15,"*-S*") // contains "-s" =COUNTIF(B5:B15,"*x*") // contains "x"

नोट: COUNTIF केस-संवेदी नहीं है।

एक सेल संदर्भ के साथ

आप मापदंड के लिए किसी अन्य कक्ष की सामग्री का उपयोग करने के लिए इस सूत्र को आसानी से समायोजित कर सकते हैं। उदाहरण के लिए, यदि A1 में वह पाठ शामिल है जिसे आप मिलान करना चाहते हैं, तो आप उपयोग कर सकते हैं:

=COUNTIF(range,"*"&A1&"*")

विशिष्ट संख्याओं की गणना करें

यदि आप किसी विशेष संख्या की तलाश कर रहे हैं और कोशिकाओं में संख्यात्मक डेटा हैं तो ऊपर COUNTIF सूत्र काम नहीं करेगा। इसका कारण यह है कि वाइल्डकार्ड स्वतः ही COUNTIF को केवल पाठ के लिए देखता है (यानी सिर्फ 2 के बजाय "2" की तलाश करता है)। क्योंकि एक पाठ मूल्य कभी भी एक सच्चे नंबर में नहीं मिलेगा, COUNTIF शून्य होगा।

संख्यात्मक सामग्री में एक विशिष्ट संख्या की गणना करने के लिए, आप SEARCH फ़ंक्शन और ISNUMBER फ़ंक्शन के आधार पर एक अलग सूत्र का उपयोग कर सकते हैं:

=SUMPRODUCT(--(ISNUMBER(SEARCH(text,range))))

इस सूत्र में, पाठ वह पाठ है जिसे आप खोज रहे हैं, और श्रेणी उन कोशिकाओं की श्रेणी है जिन्हें आप गिनना चाहते हैं। जब SEARCH एक मैच का पता लगाता है, तो वह एक नंबर लौटाएगा, और ISNUMBER फ़ंक्शन नंबर को TRUE या FALSE मान में बदल देगा। क्योंकि हम एक से अधिक सेल की जाँच कर रहे हैं, परिणाम एक सरणी या TRUE और FALSE मान होगा। TRUE और FALSE मानों को 1s और 0s में बदलने के लिए दोहरे-नकारात्मक का उपयोग किया जाता है, और SUMPRODUCT फ़ंक्शन अंतिम परिणाम के रूप में सरणी का योग लौटाएगा।

खोज स्वचालित रूप से सभी नंबरों को पाठ के रूप में मानती है, इसलिए यह उदाहरण के लिए, संख्या 201 में 1 होगा। इसके अलावा, स्थिति को इंगित करने के लिए वाइल्डकार्ड का उपयोग करने की आवश्यकता नहीं है, क्योंकि खोज एक सेल में सभी पाठ के माध्यम से स्वचालित रूप से दिखाई देगी।

केस-संवेदी संस्करण

केस-संवेदी गणना के लिए, आप FIND फ़ंक्शन के आधार पर सूत्र का उपयोग कर सकते हैं:

=SUMPRODUCT(--(ISNUMBER(FIND(text,range))))

यहां, खोज समारोह का उपयोग SEARCH के बजाय किया जाता है, क्योंकि FIND केस-संवेदी है। अन्य मामलों में सूत्र ऊपर वर्णित ISNUMBER + FIND सूत्र की तरह काम करता है।