एक्सेल सूत्र: चर स्तंभ के साथ अधिकतम मूल्य -

सामान्य सूत्र

=MAX(INDEX(data,0,MATCH(column,header,0)))

सारांश

डेटा के एक सेट में अधिकतम मान प्राप्त करने के लिए, जहां कॉलम चर है, आप MAX फ़ंक्शन के साथ INDEX और MATCH का उपयोग कर सकते हैं। जे 5 में सूत्र दिखाया गया है:

=MAX(INDEX(data,0,MATCH(J4,header,0)))

जहां डेटा (B5: F15) और हेडर (B4: F4) को नाम दिया गया है।

स्पष्टीकरण

नोट: यदि आप INDEX और MATCH में नए हैं, तो देखें: INDEX और MATCH का उपयोग कैसे करें

एक मानक कॉन्फ़िगरेशन में, INDEX फ़ंक्शन किसी दिए गए पंक्ति और स्तंभ पर एक मान प्राप्त करता है। उदाहरण के लिए, दिए गए रेंज में पंक्ति 2 और कॉलम 3 पर मान प्राप्त करने के लिए:

=INDEX(range,2,3) // get value at row 2, column 3

हालांकि, INDEX की एक विशेष चाल है - पूरे कॉलम और पंक्तियों को पुनः प्राप्त करने की क्षमता। वाक्यविन्यास में "अन्य" तर्क के लिए शून्य की आपूर्ति शामिल है। यदि आप एक संपूर्ण स्तंभ चाहते हैं, तो आप पंक्ति को शून्य के रूप में आपूर्ति करते हैं। यदि आप संपूर्ण पंक्ति चाहते हैं, तो आप कॉलम को शून्य के रूप में आपूर्ति करते हैं:

=INDEX(data,0,n) // retrieve column n =INDEX(data,n,0) // retrieve row n

दिखाए गए उदाहरण में, हम किसी दिए गए कॉलम में अधिकतम मूल्य प्राप्त करना चाहते हैं। मोड़ यह है कि कॉलम को परिवर्तनशील होना चाहिए ताकि इसे आसानी से बदला जा सके। F5 में, सूत्र है:

=MAX(INDEX(data,0,MATCH(J4,header,0)))

अंदर से बाहर काम करते हुए, हम पहले सेल J4 में अनुरोध किए गए कॉलम के "इंडेक्स" को प्राप्त करने के लिए MATCH फ़ंक्शन का उपयोग करते हैं:

MATCH(J4,header,0) // get column index

J4 में "ग्रीन" के साथ, MATCH फ़ंक्शन 3 लौटता है, क्योंकि ग्रीन नाम रेंज हेडर में तीसरा मान है । MATCH के परिणाम आने के बाद, सूत्र को इसके लिए सरल बनाया जा सकता है:

=MAX(INDEX(data,0,3))

पंक्ति संख्या के रूप में प्रदान किए गए शून्य के साथ, INDEX नामित श्रेणी डेटा के कॉलम 3 में सभी मान लौटाता है । परिणाम इस तरह से एक सरणी में अधिकतम समारोह में वापस आ गया है:

=MAX((83;54;35;17;85;16;70;72;65;93;91))

और MAX अंतिम परिणाम देता है, 93।

न्यूनतम मूल्य

एक चर स्तंभ के साथ न्यूनतम मूल्य प्राप्त करने के लिए, आप केवल MAX फ़ंक्शन को MIN फ़ंक्शन से बदल सकते हैं। J6 में सूत्र है:

=MIN(INDEX(data,0,MATCH(J4,header,0)))

फिल्टर के साथ

इस समस्या को हल करने के लिए नए फ़िल्टर फ़ंक्शन का भी उपयोग किया जा सकता है, क्योंकि फ़िल्टर डेटा को पंक्ति या स्तंभ द्वारा फ़िल्टर कर सकता है। चाल एक तार्किक फिल्टर का निर्माण करना है जो अन्य स्तंभों को बाहर कर देगा। COUNTIF इस मामले में अच्छी तरह से काम करता है, लेकिन इसे "बैकवर्ड" से कॉन्फ़िगर किया जाना चाहिए, J4 के साथ सीमा के रूप में, और मापदंड के लिए हैडर :

=MAX(FILTER(data,COUNTIF(J4,header)))

COUNTIF के चलने के बाद, हमारे पास:

=MAX(FILTER(data,(0,0,1,0,0)))

और FILTER अधिकतम MAX कॉलम को वितरित करता है, जैसा कि ऊपर दिए गए INDEX फ़ंक्शन के अनुसार है।

COUNTIF के विकल्प के रूप में, आप इसके बजाय ISNUMBER + MATCH का उपयोग कर सकते हैं:

=MAX(FILTER(data,ISNUMBER(MATCH(header,J4,0))))

MATCH फ़ंक्शन को फिर से "पीछे की ओर" सेट किया जाता है, जिससे हमें 5 मानों के साथ एक सरणी मिलती है जो तार्किक फ़िल्टर के रूप में काम करेगा। ISNUMBER और MATCH चलाने के बाद, हमारे पास:

=MAX(FILTER(data,(FALSE,FALSE,TRUE,FALSE,FALSE)))

और फिल्टर फिर से अधिकतम करने के लिए 3 कॉलम बचाता है।